home *** CD-ROM | disk | FTP | other *** search
/ Mission 3 / Mission 3.zip / Mission 3.iso / zugabe / va45 / visual45 / library / extend / file.s < prev    next >
Text File  |  1998-05-23  |  6KB  |  244 lines
  1.     ifd LIB_FIND_TEXT_IN_FILE
  2.  
  3. ;------------------------------------------------------------------------------
  4. ; Method name : -
  5. ; Asm label   : GWVA_FILE_RETURN_TEXT_IN_FILE
  6. ; Description : Recherche d'une chaine de caractère dans un ficher et recopie
  7. ; Description : de la ligne dans un buffer
  8. ;
  9. ; Rq  : Les lignes du fichier doivent impérativement se terminer par #rc
  10. ; 
  11. ; in  : a0.l = pointeur sur la chaine du nom de fichier
  12. ; in  : a1.l = chaine de caractère à rechercher
  13. ; in  : a2.l = pointeur sur un buffer où stocker résultat + calcul intermédiaire
  14. ; in  : d0.l = taille du buffer pointer par a2
  15. ; out : d7.w = GWVA_NO_ERROR_GENERIC si pas d'erreur, GWVA_ERROR_GENERIC sinon
  16. ; out : (a2) = copie de la chaine de caractères cherchée jusqu'au #rc, remplacé
  17. ;       par un 0.b
  18. ;
  19. ; 16/05/98 : Création
  20. ;------------------------------------------------------------------------------
  21. GWVA_FILE_RETURN_TEXT_IN_FILE:
  22.  
  23.     move.l d0,d5    ; d5 = taille buffer tout du long
  24.  
  25.     save.l d0/d5/a1/a2
  26.     FILE_OPEN read,(a0),d7
  27.     load.l d0/d5/a1/a2
  28.     tst d7
  29.     bmi .error
  30.  
  31.     clr.l d1        ; buff temp
  32.     clr.l d2        ; string to comp
  33.     move.l d0,d3
  34.  
  35.     ; a1 = ptr sur début string à comparer tout du long
  36.     ; a2 = ptr sur début buffer tout du long
  37.  
  38. .load_some_more:
  39.     save.l d1-d3/d5/a1-a2
  40.     move.l a2,a0
  41.     add.l d1,a0
  42.     FREAD a0,d3,d7
  43.     load.l d1-d3/d5/a1-a2
  44.     tst.l d0
  45.     beq .error2
  46.     add.l d1,d0
  47.     add.l d1,d3
  48.  
  49. .compare_more:
  50.     move.b (a2,d1.l),d6    ; dans buffer
  51.     cmp.b (a1,d2.l),d6    : == string ??
  52.     bne.s .badcomp
  53.  
  54.     addq.l #1,d2    ; bonne comparaison
  55.     tst.b (a1,d2.l)
  56.     bne.s .for_both    ; pas rendu à la fin de la comparaison
  57.  
  58.  
  59.     move.l a1,a3    ; on recopie le tout en tête de buffer
  60.     move.l a2,a4
  61.     move.l d2,d4    ; d2=long chaine de comparaison à recopier donc
  62.     subq #1,d4
  63. .cp:    move.b (a3)+,(a4)+
  64.     dbf d4,.cp
  65.  
  66. .copy_ok:    addq.l #1,d1    ; recopie ce qui suivait la string dans buffer
  67.     cmp.l d1,d0
  68.     beq.s .reload_encore
  69.  
  70.     move.b (a2,d1.l),d4
  71.     cmp.b #rc,d4
  72.     beq.s .finito
  73.     move.b d4,(a4)+
  74.     bra.s .copy_ok
  75.  
  76. .reload_encore:
  77.     move.l a2,d0
  78.     add.l d5,d0
  79.     sub.l a4,d0
  80.     save.l a4
  81.     FREAD a4,d0,d7    ; on sauve rien de plus : c'est fini
  82.     load.l a4
  83. .sear:    cmp.b #rc,(a4)+    ; chaque ligne doit se terminer par rc
  84.     bne.s .sear
  85.     lea -1(a4),a4
  86.  
  87. .finito:    clr.b (a4)+
  88.     bra.s .fin_ok
  89.  
  90. .badcomp:    clr.l d2
  91. *    bra.s .compare_more    ; bug algorithmique : si recherche ABC
  92.             ; et on a : ABABC : trouve pas ...
  93.     ; ici ca va car on a toujours le champs d'avant qui est spécial
  94.  
  95. .for_both:    addq.l #1,d1
  96.  
  97.     cmp.l d1,d0
  98.     bne.s .compare_more
  99.  
  100.  
  101.     tst.l d2
  102.     beq.s .pas_coupe
  103.  
  104.     move.l a1,a3        ; coupé
  105.     move.l a2,a4
  106.     move.l d2,d4
  107.     subq #1,d4
  108. .cp2:    move.b (a3)+,(a4)+
  109.     dbf d4,.cp2
  110.  
  111.     move.l d2,d1    ; buff temp
  112.     move.l d5,d3
  113.     sub.l d1,d3        ; how many to load
  114.     bra .load_some_more
  115.  
  116. .pas_coupe:    cmp.l d3,d0
  117.     bne.s .error2
  118.  
  119.     clr.l d1        ; buff temp
  120.     *clr.l d2        ; string to comp
  121.     move.l d5,d3
  122.     bra .load_some_more
  123.  
  124. .fin_ok:    FCLOSE d7
  125.     move.w #GWVA_NO_ERROR_GENERIC,d7
  126.     rts
  127.  
  128. .error2:    FCLOSE d7
  129. .error:    move.w #GWVA_ERROR_GENERIC,d7
  130.     rts
  131.  
  132.     endc    ; ifd LIB_FIND_TEXT_IN_FILE
  133.  
  134.     ifd LIB_GET_FLENGTH
  135.  
  136. ;------------------------------------------------------------------------------
  137. ; Method name : -
  138. ; Asm label   : GWVA_FILE_RETURN_LENGTH
  139. ; Description : Renvoie la taille d'un fichier
  140. ;
  141. ; in  : a0.l = pointeur sur la chaine du nom de fichier
  142. ; out : d0.l = longueur du fichier ou <=0 si erreur
  143. ;
  144. ; 15/03/98 : Création
  145. ;------------------------------------------------------------------------------
  146. GWVA_FILE_RETURN_LENGTH:
  147.  
  148.     save.l a0
  149.     FGETDTA
  150.  
  151.     save.l d0        ; d0.l = adresse ancien DTA
  152.     FSETDTA GWVA_ROOT_DTA
  153.     load.l d0
  154.     load.l a0        ; a0.l = ptr sur le nom du fichier
  155.  
  156.     save.l d0
  157.     FSFIRST #FA_ARCHIVE|FA_HIDDEN|FA_READONLY,(a0)
  158.     load.l a0        ; a0.l = adresse ancien DTA
  159.  
  160.     save.w d0        ; d0.w code d'erreur de FSFIRST
  161.     FSETDTA (a0)
  162.     load.w d0
  163.     ext.l d0
  164.     bmi.s .erreur
  165.     move.l GWVA_ROOT_DTA+d_lenght,d0
  166. .erreur:    rts
  167.  
  168.     endc    ; ifd LIB_GET_FLENGTH
  169.  
  170.  
  171.     ifd LIB_LOAD_FILE_IN_MEM
  172.  
  173.  ifnd LIB_GET_FLENGTH
  174.   fail    ; LIB_LOAD_FILE_IN_MEM a besoin de la librairie LIB_GET_FLENGTH
  175.   end
  176.  endc
  177.  
  178. ;------------------------------------------------------------------------------
  179. ; Method name : -
  180. ; Asm label   : GWVA_FILE_LOAD_IN_MEM
  181. ; Description : Charge un fichier en allouant la mémoire par MXALLOC
  182. ;
  183. ; Rq  : Nécessite la librairie LIB_GET_FLENGTH
  184. ; 
  185. ; in  : a0.l = pointeur sur la chaine du nom de fichier
  186. ; in  : d0.w = mode d'allocation de la mémoire (voir mxalloc) - constantes définies
  187. ; out : a0.l = pointeur sur le fichier chargé
  188. ; out : d0.l = longueur du fichier ou <=0 si erreur
  189. ;
  190. ; 15/03/98 : Création
  191. ;------------------------------------------------------------------------------
  192. GWVA_FILE_LOAD_IN_MEM:
  193.  
  194.     save.l d0/a0
  195.     bsr GWVA_FILE_RETURN_LENGTH
  196.     load.l d1/a0    ; d1.w = mode allocation MXALLOC
  197.     tst.l d0
  198.     ble.s .error_name_file
  199.  
  200.     save.l d0/a0    ; d0.l = longueur du fichier
  201.     MXALLOC d1,d0
  202.     load.l d1/a0    ; d1.l = longeur, a0.l = ptr nom
  203.  
  204.     tst.l d0        ; d0.l = pointeur la zone malloc
  205.     beq.s .error_allocation_mem
  206.  
  207.     save.l d0/d1    ; d0.l = ptr buffer, d1.l = longeur
  208.     FILE_OPEN read,(a0),d7
  209.     load.l d0/d1
  210.     tst d7
  211.     bmi.s .error_open_file
  212.     save.l d0/d1
  213.     FREAD d0,d1,d7
  214.     save.l d0
  215.     FCLOSE d7
  216.     load.l d2        ; d2.l = longueur du fichier chargé
  217.     load.l d0/d1
  218.  
  219.     cmp.l d2,d1
  220.     bne.s .error_read_file
  221.     move.l d0,a0    ; a0.l = ptr buffer
  222.     move.l d1,d0    ; longueur
  223. .error_name_file:
  224.     rts
  225.  
  226. .error_allocation_mem:
  227.     move.l #GWVA_ERROR_MALLOC,d0
  228.     rts
  229. .error_open_file:
  230.     save.w d7
  231.     MFREE d0
  232.     load.w d7
  233.     move.w d7,d0
  234.     ext.l d0
  235.     rts
  236.  
  237. .error_read_file:
  238.     MFREE d0
  239.     move.l #GWVA_ERROR_READ,d0
  240.     rts
  241.  
  242.     endc    ; ifd LIB_LOAD_FILE_IN_MEM
  243.  
  244.